f_dst_t_cdf Function

public impure function f_dst_t_cdf(x, df, mu, sigma, tail) result(p)

Impure wrapper function for f_dst_t_cdf_core. Handles optional arguments and invalid values for arguments.

Arguments

Type IntentOptional Attributes Name
real(kind=wp), intent(in) :: x

sample position
real(kind=wp), intent(in) :: df

degrees of freedom
real(kind=wp), intent(in), optional :: mu

distribution location (mean)
real(kind=wp), intent(in), optional :: sigma

distribution dispersion/scale (standard deviation)
character(len=*), intent(in), optional :: tail

tail options

Return Value real(kind=wp)

returned probability integral


Calls

proc~~f_dst_t_cdf~~CallsGraph proc~f_dst_t_cdf f_dst_t_cdf proc~f_dst_t_cdf_core f_dst_t_cdf_core proc~f_dst_t_cdf->proc~f_dst_t_cdf_core proc~s_err_print s_err_print proc~f_dst_t_cdf->proc~s_err_print proc~f_dst_betai_core f_dst_betai_core proc~f_dst_t_cdf_core->proc~f_dst_betai_core proc~f_utl_r2c f_utl_r2c proc~s_err_print->proc~f_utl_r2c

Called by

proc~~f_dst_t_cdf~~CalledByGraph proc~f_dst_t_cdf f_dst_t_cdf interface~fsml_t_cdf fsml_t_cdf interface~fsml_t_cdf->proc~f_dst_t_cdf

Source Code

impure function f_dst_t_cdf(x, df, mu, sigma, tail) result(p)

! ==== Description
!! Impure wrapper function for `f_dst_t_cdf_core`.
!! Handles optional arguments and invalid values for arguments.

! ==== Declarations
  real(wp)        , intent(in)           :: x           !! sample position
  real(wp)        , intent(in)           :: df          !! degrees of freedom
  real(wp)        , intent(in), optional :: mu          !! distribution location (mean)
  real(wp)        , intent(in), optional :: sigma       !! distribution dispersion/scale (standard deviation)
  character(len=*), intent(in), optional :: tail        !! tail options
  real(wp)                               :: mu_w        !! final value of mu
  real(wp)                               :: sigma_w     !! final value of sigma
  character(len=16)                      :: tail_w      !! final tail option
  real(wp)                               :: p           !! returned probability integral

! ==== Instructions

! ---- handle input

  ! assume location/mean = 0, overwrite if specified
  mu_w = 0.0_wp
  if (present(mu)) mu_w = mu

  ! assume sigma = 1, overwrite if specified
  sigma_w = 1.0_wp
  if (present(sigma)) sigma_w = sigma

  ! assume left-tailed, overwrite if specified
  tail_w = "left"
  if (present(tail)) tail_w = tail

  ! check if sigma value is valid
  if (sigma_w .le. 0.0_wp) then
     ! write error message and assign sentinel value if value invalid
     call s_err_print(fsml_error(1))
     p = c_sentinel_r
     return
  endif

  ! check if tail options are valid
  if (tail_w .ne. "left" .and. tail_w .ne. "right" .and. &
     &tail_w .ne. "two" .and. tail_w .ne. "confidence") then
     ! write error message and assign sentinel value if invalid
     call s_err_print(fsml_error(2))
     p = c_sentinel_r
     return
  endif

  ! check if degrees of freedom value is valid
  if (df .le. 0.0_wp) then
     ! write error message and assign sentinel value if invalid
     call s_err_print(fsml_error(1))
     p = c_sentinel_r
     return
  endif

! ---- compute CDF

  ! call pure function to calculate probability integral
  p = f_dst_t_cdf_core(x, df, mu_w, sigma_w, tail_w)

end function f_dst_t_cdf